Add a complete priority inheritance implementation to the scheduler (all mutex ownership and queue_send calls are inheritable). Priorities are differential so that dispatch depends on the runnable range of priorities. Codec priority can therefore be raised in small steps (pcmbuf updated to enable). Simplify the kernel functions to ease implementation and use the same kernel.c for both sim and target (I'm tired of maintaining two ;_). 1) Not sure if a minor audio break at first buffering issue will exist on large-sector disks (the main mutex speed issue was genuinely resolved earlier). At this point it's best dealt with at the buffering level. It seems a larger filechunk could be used again. 2) Perhaps 64-bit sims will have some minor issues (finicky) but a backroll of the code of concern there is a 5-minute job. All kernel objects become incompatible so a full rebuild and update is needed.

git-svn-id: svn://svn.rockbox.org/rockbox/trunk@16791 a1c6a512-1295-4272-9138-f99709370657

4 files changed, 78 insertions, 4 deletions

diff --git a/firmware/target/arm/ffs-arm.S b/firmware/target/arm/ffs-arm.S
new file mode 100644
index 0000000000..bb888ab558
--- /dev/null
+++ b/firmware/target/arm/ffs-arm.S
@@ -0,0 +1,74 @@
+/***************************************************************************
+ *             __________               __   ___.
+ *   Open      \______   \ ____   ____ |  | _\_ |__   _______  ___
+ *   Source     |       _//  _ \_/ ___\|  |/ /| __ \ /  _ \  \/  /
+ *   Jukebox    |    |   (  <_> )  \___|    < | \_\ (  <_> > <  <
+ *   Firmware   |____|_  /\____/ \___  >__|_ \|___  /\____/__/\_ \
+ *                     \/            \/     \/    \/            \/
+ * $Id$
+ *
+ * Copyright (C) 2008 by Michael Sevakis
+ *
+ * All files in this archive are subject to the GNU General Public License.
+ * See the file COPYING in the source tree root for full license agreement.
+ *
+ * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
+ * KIND, either express or implied.
+ *
+ ****************************************************************************/
+ #include "config.h"
+
+/****************************************************************************
+ * int find_first_set_bit(uint32_t val);
+ *
+ * Find the index of the least significant set bit in the 32-bit word.
+ *
+ * return values:
+ *   0  - bit 0 is set
+ *   1  - bit 1 is set
+ *   ...
+ *   31 - bit 31 is set
+ *   32 - no bits set
+ ****************************************************************************/
+    .align  2
+    .global find_first_set_bit
+    .type   find_first_set_bit,%function
+find_first_set_bit:
+    @ Standard trick to isolate bottom bit in r0 or 0 if r0 = 0 on entry
+    rsb     r2, r0, #0               @ r1 = r0 & -r0
+    ands    r1, r0, r2               @
+    
+    @ now r1 has at most one set bit, call this X
+    
+#if ARM_ARCH >= 5
+    clz     r0, r1                   @ Get lead 0's count
+    rsbne   r0, r0, #31              @ lead 0's -> bit index
+    bx      lr                       @
+#else
+    @ this is the ffs algorithm devised by D.Seal and posted to
+    @ comp.sys.arm on 16 Feb 1994.
+    @
+    @ Output modified to suit Rockbox purposes.
+
+    adr     r2, L_ffs_table
+    orrne   r1, r1, r1, lsl #4       @ r1 = X * 0x11
+    orrne   r1, r1, r1, lsl #6       @ r1 = X * 0x451
+    rsbne   r1, r1, r1, lsl #16      @ r1 = X * 0x0450fbaf
+
+    @ now lookup in table indexed on top 6 bits of r1
+    ldrb    r0, [ r2, r1, lsr #26 ]  @
+    bx      lr                       @
+
+L_ffs_table:
+    @        0   1   2   3   4   5   6   7
+    @----------------------------------------------
+    .byte   32,  0,  1, 12,  2,  6,  0, 13  @  0- 7
+    .byte    3,  0,  7,  0,  0,  0,  0, 14  @  8-15
+    .byte   10,  4,  0,  0,  8,  0,  0, 25  @ 16-23
+    .byte    0,  0,  0,  0,  0, 21, 27, 15  @ 24-31
+    .byte   31, 11,  5,  0,  0,  0,  0,  0  @ 32-39
+    .byte    9,  0,  0, 24,  0,  0, 20, 26  @ 40-47
+    .byte   30,  0,  0,  0,  0, 23,  0, 19  @ 48-55
+    .byte   29,  0, 22, 18, 28, 17, 16,  0  @ 56-63
+#endif
+    .size   find_first_set_bit, .-find_first_set_bit
diff --git a/firmware/target/arm/i2c-pp.c b/firmware/target/arm/i2c-pp.c
index 092a59be84..1cfbfaeff1 100644
--- a/firmware/target/arm/i2c-pp.c
+++ b/firmware/target/arm/i2c-pp.c
@@ -45,7 +45,7 @@ static int pp_i2c_wait_not_busy(void)
          if (!(I2C_STATUS & I2C_BUSY)) {
             return 0;
          }
-         priority_yield();
+         yield();
     }
 
     return -1;
diff --git a/firmware/target/arm/s3c2440/gigabeat-fx/ata-meg-fx.c b/firmware/target/arm/s3c2440/gigabeat-fx/ata-meg-fx.c
index 1f5c5c8fbe..f5d37baf5f 100644
--- a/firmware/target/arm/s3c2440/gigabeat-fx/ata-meg-fx.c
+++ b/firmware/target/arm/s3c2440/gigabeat-fx/ata-meg-fx.c
@@ -128,7 +128,7 @@ void copy_read_sectors(unsigned char* buf, int wordcount)
 
     /* Wait for transfer to complete */
     while((DSTAT0 & 0x000fffff))
-        priority_yield();
+        yield();
     /* Dump cache for the buffer  */
 }
 #endif
diff --git a/firmware/target/arm/sandisk/ata-c200_e200.c b/firmware/target/arm/sandisk/ata-c200_e200.c
index c1c0cb3e8c..747cb17ca1 100644
--- a/firmware/target/arm/sandisk/ata-c200_e200.c
+++ b/firmware/target/arm/sandisk/ata-c200_e200.c
@@ -198,7 +198,7 @@ static bool sd_poll_status(unsigned int trigger, long timeout)
         if (TIME_AFTER(time, next_yield))
         {
             long ty = USEC_TIMER;
-            priority_yield();
+            yield();
             timeout += USEC_TIMER - ty;
             next_yield = ty + MIN_YIELD_PERIOD;
         }
@@ -317,7 +317,7 @@ static int sd_wait_for_state(unsigned int state, int id)
         us = USEC_TIMER;
         if (TIME_AFTER(us, next_yield))
         {
-            priority_yield();
+            yield();
             timeout += USEC_TIMER - us;
             next_yield = us + MIN_YIELD_PERIOD;
         }