diff options
Diffstat (limited to 'firmware/target/sh')
-rwxr-xr-x | firmware/target/sh/memcpy-sh.S | 217 | ||||
-rwxr-xr-x | firmware/target/sh/memmove-sh.S | 220 | ||||
-rwxr-xr-x | firmware/target/sh/memset-sh.S | 107 | ||||
-rwxr-xr-x | firmware/target/sh/strlen-sh.S | 94 |
4 files changed, 638 insertions, 0 deletions
diff --git a/firmware/target/sh/memcpy-sh.S b/firmware/target/sh/memcpy-sh.S new file mode 100755 index 0000000000..0b5e086be9 --- /dev/null +++ b/firmware/target/sh/memcpy-sh.S | |||
@@ -0,0 +1,217 @@ | |||
1 | /*************************************************************************** | ||
2 | * __________ __ ___. | ||
3 | * Open \______ \ ____ ____ | | _\_ |__ _______ ___ | ||
4 | * Source | _// _ \_/ ___\| |/ /| __ \ / _ \ \/ / | ||
5 | * Jukebox | | ( <_> ) \___| < | \_\ ( <_> > < < | ||
6 | * Firmware |____|_ /\____/ \___ >__|_ \|___ /\____/__/\_ \ | ||
7 | * \/ \/ \/ \/ \/ | ||
8 | * $Id$ | ||
9 | * | ||
10 | * Copyright (C) 2004-2005 by Jens Arnold | ||
11 | * | ||
12 | * All files in this archive are subject to the GNU General Public License. | ||
13 | * See the file COPYING in the source tree root for full license agreement. | ||
14 | * | ||
15 | * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY | ||
16 | * KIND, either express or implied. | ||
17 | * | ||
18 | ****************************************************************************/ | ||
19 | #include "config.h" | ||
20 | |||
21 | .section .icode,"ax",@progbits | ||
22 | |||
23 | .align 2 | ||
24 | .global _memcpy | ||
25 | .global ___memcpy_fwd_entry | ||
26 | .type _memcpy,@function | ||
27 | |||
28 | /* Copies <length> bytes of data in memory from <source> to <dest> | ||
29 | * This version is optimized for speed | ||
30 | * | ||
31 | * arguments: | ||
32 | * r4 - destination address | ||
33 | * r5 - source address | ||
34 | * r6 - length | ||
35 | * | ||
36 | * return value: | ||
37 | * r0 - destination address (like ANSI version) | ||
38 | * | ||
39 | * register usage: | ||
40 | * r0 - data / scratch | ||
41 | * r1 - 2nd data / scratch | ||
42 | * r2 - scratch | ||
43 | * r3 - first long bound / adjusted end address (only if >= 11 bytes) | ||
44 | * r4 - current dest address | ||
45 | * r5 - current source address | ||
46 | * r6 - source end address | ||
47 | * r7 - stored dest start address | ||
48 | * | ||
49 | * The instruction order is devised in a way to utilize the pipelining | ||
50 | * of the SH1 to the max. The routine also tries to utilize fast page mode. | ||
51 | */ | ||
52 | |||
53 | _memcpy: | ||
54 | mov r4,r7 /* store dest for returning */ | ||
55 | ___memcpy_fwd_entry: | ||
56 | add #-8,r4 /* offset for early increment (max. 2 longs) */ | ||
57 | mov #11,r0 | ||
58 | cmp/hs r0,r6 /* at least 11 bytes to copy? (ensures 2 aligned longs) */ | ||
59 | add r5,r6 /* r6 = source_end */ | ||
60 | bf .start_b2 /* no: jump directly to byte loop */ | ||
61 | |||
62 | mov #3,r0 | ||
63 | neg r5,r3 | ||
64 | and r0,r3 /* r3 = (4 - align_offset) % 4 */ | ||
65 | tst r3,r3 /* already aligned? */ | ||
66 | bt .end_b1 /* yes: skip leading byte loop */ | ||
67 | |||
68 | add r5,r3 /* r3 = first source long bound */ | ||
69 | |||
70 | /* leading byte loop: copies 0..3 bytes */ | ||
71 | .loop_b1: | ||
72 | mov.b @r5+,r0 /* load byte & increment source addr */ | ||
73 | add #1,r4 /* increment dest addr */ | ||
74 | mov.b r0,@(7,r4) /* store byte */ | ||
75 | cmp/hi r5,r3 /* runs r5 up to first long bound */ | ||
76 | bt .loop_b1 | ||
77 | /* now r5 is always at a long boundary */ | ||
78 | /* -> memory reading is done in longs for all dest alignments */ | ||
79 | |||
80 | /* selector for main copy loop */ | ||
81 | .end_b1: | ||
82 | mov #3,r1 | ||
83 | and r4,r1 /* r1 = dest alignment offset */ | ||
84 | mova .jmptab,r0 | ||
85 | mov.b @(r0,r1),r1 /* select appropriate main loop */ | ||
86 | add r0,r1 | ||
87 | mov r6,r3 /* move end address to r3 */ | ||
88 | jmp @r1 /* and jump to it */ | ||
89 | add #-7,r3 /* adjust end addr for main loops doing 2 longs/pass */ | ||
90 | |||
91 | /** main loops, copying 2 longs per pass to profit from fast page mode **/ | ||
92 | |||
93 | /* long aligned destination (fastest) */ | ||
94 | .align 2 | ||
95 | .loop_do0: | ||
96 | mov.l @r5+,r1 /* load first long & increment source addr */ | ||
97 | add #16,r4 /* increment dest addr & account for decrementing stores */ | ||
98 | mov.l @r5+,r0 /* load second long & increment source addr */ | ||
99 | cmp/hi r5,r3 /* runs r5 up to last or second last long bound */ | ||
100 | mov.l r0,@-r4 /* store second long */ | ||
101 | mov.l r1,@-r4 /* store first long; NOT ALIGNED - no speed loss here! */ | ||
102 | bt .loop_do0 | ||
103 | |||
104 | add #4,r3 /* readjust end address */ | ||
105 | cmp/hi r5,r3 /* one long left? */ | ||
106 | bf .start_b2 /* no, jump to trailing byte loop */ | ||
107 | |||
108 | mov.l @r5+,r0 /* load last long & increment source addr */ | ||
109 | add #4,r4 /* increment dest addr */ | ||
110 | bra .start_b2 /* jump to trailing byte loop */ | ||
111 | mov.l r0,@(4,r4) /* store last long */ | ||
112 | |||
113 | /* word aligned destination (long + 2) */ | ||
114 | .align 2 | ||
115 | .loop_do2: | ||
116 | mov.l @r5+,r1 /* load first long & increment source addr */ | ||
117 | add #16,r4 /* increment dest addr */ | ||
118 | mov.l @r5+,r0 /* load second long & increment source addr */ | ||
119 | cmp/hi r5,r3 /* runs r5 up to last or second last long bound */ | ||
120 | mov.w r0,@-r4 /* store low word of second long */ | ||
121 | xtrct r1,r0 /* extract low word of first long & high word of second long */ | ||
122 | mov.l r0,@-r4 /* and store as long */ | ||
123 | swap.w r1,r0 /* get high word of first long */ | ||
124 | mov.w r0,@-r4 /* and store it */ | ||
125 | bt .loop_do2 | ||
126 | |||
127 | add #4,r3 /* readjust end address */ | ||
128 | cmp/hi r5,r3 /* one long left? */ | ||
129 | bf .start_b2 /* no, jump to trailing byte loop */ | ||
130 | |||
131 | mov.l @r5+,r0 /* load last long & increment source addr */ | ||
132 | add #4,r4 /* increment dest addr */ | ||
133 | mov.w r0,@(6,r4) /* store low word */ | ||
134 | shlr16 r0 /* get high word */ | ||
135 | bra .start_b2 /* jump to trailing byte loop */ | ||
136 | mov.w r0,@(4,r4) /* and store it */ | ||
137 | |||
138 | /* jumptable for loop selector */ | ||
139 | .align 2 | ||
140 | .jmptab: | ||
141 | .byte .loop_do0 - .jmptab /* placed in the middle because the SH1 */ | ||
142 | .byte .loop_do1 - .jmptab /* loads bytes sign-extended. Otherwise */ | ||
143 | .byte .loop_do2 - .jmptab /* the last loop would be out of reach */ | ||
144 | .byte .loop_do3 - .jmptab /* of the offset range. */ | ||
145 | |||
146 | /* byte aligned destination (long + 1) */ | ||
147 | .align 2 | ||
148 | .loop_do1: | ||
149 | mov.l @r5+,r1 /* load first long & increment source addr */ | ||
150 | add #16,r4 /* increment dest addr */ | ||
151 | mov.l @r5+,r0 /* load second long & increment source addr */ | ||
152 | cmp/hi r5,r3 /* runs r5 up to last or second last long bound */ | ||
153 | mov.b r0,@-r4 /* store low byte of second long */ | ||
154 | shlr8 r0 /* get upper 3 bytes */ | ||
155 | mov r1,r2 /* copy first long */ | ||
156 | shll16 r2 /* move low byte of first long all the way up, .. */ | ||
157 | shll8 r2 | ||
158 | or r2,r0 /* ..combine with the 3 bytes of second long.. */ | ||
159 | mov.l r0,@-r4 /* ..and store as long */ | ||
160 | shlr8 r1 /* get middle 2 bytes */ | ||
161 | mov.w r1,@-r4 /* store as word */ | ||
162 | shlr16 r1 /* get upper byte */ | ||
163 | mov.b r1,@-r4 /* and store */ | ||
164 | bt .loop_do1 | ||
165 | |||
166 | add #4,r3 /* readjust end address */ | ||
167 | .last_do13: | ||
168 | cmp/hi r5,r3 /* one long left? */ | ||
169 | bf .start_b2 /* no, jump to trailing byte loop */ | ||
170 | |||
171 | mov.l @r5+,r0 /* load last long & increment source addr */ | ||
172 | add #12,r4 /* increment dest addr */ | ||
173 | mov.b r0,@-r4 /* store low byte */ | ||
174 | shlr8 r0 /* get middle 2 bytes */ | ||
175 | mov.w r0,@-r4 /* store as word */ | ||
176 | shlr16 r0 /* get upper byte */ | ||
177 | mov.b r0,@-r4 /* and store */ | ||
178 | bra .start_b2 /* jump to trailing byte loop */ | ||
179 | add #-4,r4 /* readjust destination */ | ||
180 | |||
181 | /* byte aligned destination (long + 3) */ | ||
182 | .align 2 | ||
183 | .loop_do3: | ||
184 | mov.l @r5+,r1 /* load first long & increment source addr */ | ||
185 | add #16,r4 /* increment dest addr */ | ||
186 | mov.l @r5+,r0 /* load second long & increment source addr */ | ||
187 | mov r1,r2 /* copy first long */ | ||
188 | mov.b r0,@-r4 /* store low byte of second long */ | ||
189 | shlr8 r0 /* get middle 2 bytes */ | ||
190 | mov.w r0,@-r4 /* store as word */ | ||
191 | shlr16 r0 /* get upper byte */ | ||
192 | shll8 r2 /* move lower 3 bytes of first long one up.. */ | ||
193 | or r2,r0 /* ..combine with the 1 byte of second long.. */ | ||
194 | mov.l r0,@-r4 /* ..and store as long */ | ||
195 | shlr16 r1 /* get upper byte of first long.. */ | ||
196 | shlr8 r1 | ||
197 | cmp/hi r5,r3 /* runs r5 up to last or second last long bound */ | ||
198 | mov.b r1,@-r4 /* ..and store */ | ||
199 | bt .loop_do3 | ||
200 | |||
201 | bra .last_do13 /* handle last longword: reuse routine for (long + 1) */ | ||
202 | add #4,r3 /* readjust end address */ | ||
203 | |||
204 | /* trailing byte loop: copies 0..3 bytes (or all for < 11 in total) */ | ||
205 | .align 2 | ||
206 | .loop_b2: | ||
207 | mov.b @r5+,r0 /* load byte & increment source addr */ | ||
208 | add #1,r4 /* increment dest addr */ | ||
209 | mov.b r0,@(7,r4) /* store byte */ | ||
210 | .start_b2: | ||
211 | cmp/hi r5,r6 /* runs r5 up to end address */ | ||
212 | bt .loop_b2 | ||
213 | |||
214 | rts | ||
215 | mov r7,r0 /* return dest start address */ | ||
216 | .end: | ||
217 | .size _memcpy,.end-_memcpy | ||
diff --git a/firmware/target/sh/memmove-sh.S b/firmware/target/sh/memmove-sh.S new file mode 100755 index 0000000000..9ae9ae5fa2 --- /dev/null +++ b/firmware/target/sh/memmove-sh.S | |||
@@ -0,0 +1,220 @@ | |||
1 | /*************************************************************************** | ||
2 | * __________ __ ___. | ||
3 | * Open \______ \ ____ ____ | | _\_ |__ _______ ___ | ||
4 | * Source | _// _ \_/ ___\| |/ /| __ \ / _ \ \/ / | ||
5 | * Jukebox | | ( <_> ) \___| < | \_\ ( <_> > < < | ||
6 | * Firmware |____|_ /\____/ \___ >__|_ \|___ /\____/__/\_ \ | ||
7 | * \/ \/ \/ \/ \/ | ||
8 | * $Id$ | ||
9 | * | ||
10 | * Copyright (C) 2006 by Jens Arnold | ||
11 | * | ||
12 | * All files in this archive are subject to the GNU General Public License. | ||
13 | * See the file COPYING in the source tree root for full license agreement. | ||
14 | * | ||
15 | * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY | ||
16 | * KIND, either express or implied. | ||
17 | * | ||
18 | ****************************************************************************/ | ||
19 | #include "config.h" | ||
20 | |||
21 | .section .icode,"ax",@progbits | ||
22 | |||
23 | .align 2 | ||
24 | .global _memmove | ||
25 | .type _memmove,@function | ||
26 | |||
27 | /* Moves <length> bytes of data in memory from <source> to <dest> | ||
28 | * Regions may overlap. | ||
29 | * This version is optimized for speed, and needs the corresponding memcpy | ||
30 | * implementation for the forward copy branch. | ||
31 | * | ||
32 | * arguments: | ||
33 | * r4 - destination address | ||
34 | * r5 - source address | ||
35 | * r6 - length | ||
36 | * | ||
37 | * return value: | ||
38 | * r0 - destination address (like ANSI version) | ||
39 | * | ||
40 | * register usage: | ||
41 | * r0 - data / scratch | ||
42 | * r1 - 2nd data / scratch | ||
43 | * r2 - scratch | ||
44 | * r3 - last long bound / adjusted start address (only if >= 11 bytes) | ||
45 | * r4 - current dest address | ||
46 | * r5 - source start address | ||
47 | * r6 - current source address | ||
48 | * | ||
49 | * The instruction order is devised in a way to utilize the pipelining | ||
50 | * of the SH1 to the max. The routine also tries to utilize fast page mode. | ||
51 | */ | ||
52 | |||
53 | _memmove: | ||
54 | cmp/hi r4,r5 /* source > destination */ | ||
55 | bf .backward /* no: backward copy */ | ||
56 | mov.l .memcpy_fwd,r0 | ||
57 | jmp @r0 | ||
58 | mov r4,r7 /* store dest for returning */ | ||
59 | |||
60 | .align 2 | ||
61 | .memcpy_fwd: | ||
62 | .long ___memcpy_fwd_entry | ||
63 | |||
64 | .backward: | ||
65 | add r6,r4 /* r4 = destination end */ | ||
66 | mov #11,r0 | ||
67 | cmp/hs r0,r6 /* at least 11 bytes to copy? (ensures 2 aligned longs) */ | ||
68 | add #-8,r5 /* adjust for late decrement (max. 2 longs) */ | ||
69 | add r5,r6 /* r6 = source end - 8 */ | ||
70 | bf .start_b2r /* no: jump directly to byte loop */ | ||
71 | |||
72 | mov #-4,r3 /* r3 = 0xfffffffc */ | ||
73 | and r6,r3 /* r3 = last source long bound */ | ||
74 | cmp/hi r3,r6 /* already aligned? */ | ||
75 | bf .end_b1r /* yes: skip leading byte loop */ | ||
76 | |||
77 | .loop_b1r: | ||
78 | mov.b @(7,r6),r0 /* load byte */ | ||
79 | add #-1,r6 /* decrement source addr */ | ||
80 | mov.b r0,@-r4 /* store byte */ | ||
81 | cmp/hi r3,r6 /* runs r6 down to last long bound */ | ||
82 | bt .loop_b1r | ||
83 | |||
84 | .end_b1r: | ||
85 | mov #3,r1 | ||
86 | and r4,r1 /* r1 = dest alignment offset */ | ||
87 | mova .jmptab_r,r0 | ||
88 | mov.b @(r0,r1),r1 /* select appropriate main loop.. */ | ||
89 | add r0,r1 | ||
90 | mov r5,r3 /* copy start adress to r3 */ | ||
91 | jmp @r1 /* ..and jump to it */ | ||
92 | add #7,r3 /* adjust end addr for main loops doing 2 longs/pass */ | ||
93 | |||
94 | /** main loops, copying 2 longs per pass to profit from fast page mode **/ | ||
95 | |||
96 | /* long aligned destination (fastest) */ | ||
97 | .align 2 | ||
98 | .loop_do0r: | ||
99 | mov.l @r6,r1 /* load first long */ | ||
100 | add #-8,r6 /* decrement source addr */ | ||
101 | mov.l @(12,r6),r0 /* load second long */ | ||
102 | cmp/hi r3,r6 /* runs r6 down to first or second long bound */ | ||
103 | mov.l r0,@-r4 /* store second long */ | ||
104 | mov.l r1,@-r4 /* store first long; NOT ALIGNED - no speed loss here! */ | ||
105 | bt .loop_do0r | ||
106 | |||
107 | add #-4,r3 /* readjust end address */ | ||
108 | cmp/hi r3,r6 /* first long left? */ | ||
109 | bf .start_b2r /* no, jump to trailing byte loop */ | ||
110 | |||
111 | mov.l @(4,r6),r0 /* load first long */ | ||
112 | add #-4,r6 /* decrement source addr */ | ||
113 | bra .start_b2r /* jump to trailing byte loop */ | ||
114 | mov.l r0,@-r4 /* store first long */ | ||
115 | |||
116 | /* word aligned destination (long + 2) */ | ||
117 | .align 2 | ||
118 | .loop_do2r: | ||
119 | mov.l @r6,r1 /* load first long */ | ||
120 | add #-8,r6 /* decrement source addr */ | ||
121 | mov.l @(12,r6),r0 /* load second long */ | ||
122 | cmp/hi r3,r6 /* runs r6 down to first or second long bound */ | ||
123 | mov.w r0,@-r4 /* store low word of second long */ | ||
124 | xtrct r1,r0 /* extract low word of first long & high word of second long */ | ||
125 | mov.l r0,@-r4 /* and store as long */ | ||
126 | shlr16 r1 /* get high word of first long */ | ||
127 | mov.w r1,@-r4 /* and store it */ | ||
128 | bt .loop_do2r | ||
129 | |||
130 | add #-4,r3 /* readjust end address */ | ||
131 | cmp/hi r3,r6 /* first long left? */ | ||
132 | bf .start_b2r /* no, jump to trailing byte loop */ | ||
133 | |||
134 | mov.l @(4,r6),r0 /* load first long & decrement source addr */ | ||
135 | add #-4,r6 /* decrement source addr */ | ||
136 | mov.w r0,@-r4 /* store low word */ | ||
137 | shlr16 r0 /* get high word */ | ||
138 | bra .start_b2r /* jump to trailing byte loop */ | ||
139 | mov.w r0,@-r4 /* and store it */ | ||
140 | |||
141 | /* jumptable for loop selector */ | ||
142 | .align 2 | ||
143 | .jmptab_r: | ||
144 | .byte .loop_do0r - .jmptab_r /* placed in the middle because the SH1 */ | ||
145 | .byte .loop_do1r - .jmptab_r /* loads bytes sign-extended. Otherwise */ | ||
146 | .byte .loop_do2r - .jmptab_r /* the last loop would be out of reach */ | ||
147 | .byte .loop_do3r - .jmptab_r /* of the offset range. */ | ||
148 | |||
149 | /* byte aligned destination (long + 1) */ | ||
150 | .align 2 | ||
151 | .loop_do1r: | ||
152 | mov.l @r6,r1 /* load first long */ | ||
153 | add #-8,r6 /* decrement source addr */ | ||
154 | mov.l @(12,r6),r0 /* load second long */ | ||
155 | cmp/hi r3,r6 /* runs r6 down to first or second long bound */ | ||
156 | mov.b r0,@-r4 /* store low byte of second long */ | ||
157 | shlr8 r0 /* get upper 3 bytes */ | ||
158 | mov r1,r2 /* copy first long */ | ||
159 | shll16 r2 /* move low byte of first long all the way up, .. */ | ||
160 | shll8 r2 | ||
161 | or r2,r0 /* ..combine with the 3 bytes of second long.. */ | ||
162 | mov.l r0,@-r4 /* ..and store as long */ | ||
163 | shlr8 r1 /* get middle 2 bytes */ | ||
164 | mov.w r1,@-r4 /* store as word */ | ||
165 | shlr16 r1 /* get upper byte */ | ||
166 | mov.b r1,@-r4 /* and store */ | ||
167 | bt .loop_do1r | ||
168 | |||
169 | add #-4,r3 /* readjust end address */ | ||
170 | .last_do13r: | ||
171 | cmp/hi r3,r6 /* first long left? */ | ||
172 | bf .start_b2r /* no, jump to trailing byte loop */ | ||
173 | |||
174 | nop /* alignment */ | ||
175 | mov.l @(4,r6),r0 /* load first long */ | ||
176 | add #-4,r6 /* decrement source addr */ | ||
177 | mov.b r0,@-r4 /* store low byte */ | ||
178 | shlr8 r0 /* get middle 2 bytes */ | ||
179 | mov.w r0,@-r4 /* store as word */ | ||
180 | shlr16 r0 /* get upper byte */ | ||
181 | bra .start_b2r /* jump to trailing byte loop */ | ||
182 | mov.b r0,@-r4 /* and store */ | ||
183 | |||
184 | /* byte aligned destination (long + 3) */ | ||
185 | .align 2 | ||
186 | .loop_do3r: | ||
187 | mov.l @r6,r1 /* load first long */ | ||
188 | add #-8,r6 /* decrement source addr */ | ||
189 | mov.l @(12,r6),r0 /* load second long */ | ||
190 | mov r1,r2 /* copy first long */ | ||
191 | mov.b r0,@-r4 /* store low byte of second long */ | ||
192 | shlr8 r0 /* get middle 2 bytes */ | ||
193 | mov.w r0,@-r4 /* store as word */ | ||
194 | shlr16 r0 /* get upper byte */ | ||
195 | shll8 r2 /* move lower 3 bytes of first long one up.. */ | ||
196 | or r2,r0 /* ..combine with the 1 byte of second long.. */ | ||
197 | mov.l r0,@-r4 /* ..and store as long */ | ||
198 | shlr16 r1 /* get upper byte of first long */ | ||
199 | shlr8 r1 | ||
200 | cmp/hi r3,r6 /* runs r6 down to first or second long bound */ | ||
201 | mov.b r1,@-r4 /* ..and store */ | ||
202 | bt .loop_do3r | ||
203 | |||
204 | bra .last_do13r /* handle first longword: reuse routine for (long + 1) */ | ||
205 | add #-4,r3 /* readjust end address */ | ||
206 | |||
207 | /* trailing byte loop: copies 0..3 bytes (or all for < 11 in total) */ | ||
208 | .align 2 | ||
209 | .loop_b2r: | ||
210 | mov.b @(7,r6),r0 /* load byte */ | ||
211 | add #-1,r6 /* decrement source addr */ | ||
212 | mov.b r0,@-r4 /* store byte */ | ||
213 | .start_b2r: | ||
214 | cmp/hi r5,r6 /* runs r6 down to start address */ | ||
215 | bt .loop_b2r | ||
216 | |||
217 | rts | ||
218 | mov r4,r0 /* return dest start address */ | ||
219 | .end: | ||
220 | .size _memmove,.end-_memmove | ||
diff --git a/firmware/target/sh/memset-sh.S b/firmware/target/sh/memset-sh.S new file mode 100755 index 0000000000..9b96b93f27 --- /dev/null +++ b/firmware/target/sh/memset-sh.S | |||
@@ -0,0 +1,107 @@ | |||
1 | /*************************************************************************** | ||
2 | * __________ __ ___. | ||
3 | * Open \______ \ ____ ____ | | _\_ |__ _______ ___ | ||
4 | * Source | _// _ \_/ ___\| |/ /| __ \ / _ \ \/ / | ||
5 | * Jukebox | | ( <_> ) \___| < | \_\ ( <_> > < < | ||
6 | * Firmware |____|_ /\____/ \___ >__|_ \|___ /\____/__/\_ \ | ||
7 | * \/ \/ \/ \/ \/ | ||
8 | * $Id$ | ||
9 | * | ||
10 | * Copyright (C) 2004 by Jens Arnold | ||
11 | * | ||
12 | * All files in this archive are subject to the GNU General Public License. | ||
13 | * See the file COPYING in the source tree root for full license agreement. | ||
14 | * | ||
15 | * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY | ||
16 | * KIND, either express or implied. | ||
17 | * | ||
18 | ****************************************************************************/ | ||
19 | #include "config.h" | ||
20 | |||
21 | .section .icode,"ax",@progbits | ||
22 | |||
23 | .align 2 | ||
24 | .global _memset | ||
25 | .type _memset,@function | ||
26 | |||
27 | /* Fills a memory region with specified byte value | ||
28 | * This version is optimized for speed | ||
29 | * | ||
30 | * arguments: | ||
31 | * r4 - start address | ||
32 | * r5 - data | ||
33 | * r6 - length | ||
34 | * | ||
35 | * return value: | ||
36 | * r0 - start address (like ANSI version) | ||
37 | * | ||
38 | * register usage: | ||
39 | * r0 - temporary | ||
40 | * r1 - start address +11 for main loop | ||
41 | * r4 - start address | ||
42 | * r5 - data (spread to all 4 bytes when using long stores) | ||
43 | * r6 - current address (runs down from end to start) | ||
44 | * | ||
45 | * The instruction order below is devised in a way to utilize the pipelining | ||
46 | * of the SH1 to the max. The routine fills memory from end to start in | ||
47 | * order to utilize the auto-decrementing store instructions. | ||
48 | */ | ||
49 | |||
50 | _memset: | ||
51 | neg r4,r0 | ||
52 | and #3,r0 /* r0 = (4 - align_offset) % 4 */ | ||
53 | add #4,r0 | ||
54 | cmp/hs r0,r6 /* at least one aligned longword to fill? */ | ||
55 | add r4,r6 /* r6 = end_address */ | ||
56 | bf .no_longs /* no, jump directly to byte loop */ | ||
57 | |||
58 | extu.b r5,r5 /* start: spread data to all 4 bytes */ | ||
59 | swap.b r5,r0 | ||
60 | or r0,r5 /* data now in 2 lower bytes of r5 */ | ||
61 | swap.w r5,r0 | ||
62 | or r0,r5 /* data now in all 4 bytes of r5 */ | ||
63 | |||
64 | mov r6,r0 | ||
65 | tst #3,r0 /* r0 already long aligned? */ | ||
66 | bt .end_b1 /* yes: skip loop */ | ||
67 | |||
68 | /* leading byte loop: sets 0..3 bytes */ | ||
69 | .loop_b1: | ||
70 | mov.b r5,@-r0 /* store byte */ | ||
71 | tst #3,r0 /* r0 long aligned? */ | ||
72 | bf .loop_b1 /* runs r0 down until long aligned */ | ||
73 | |||
74 | mov r0,r6 /* r6 = last long bound */ | ||
75 | nop /* keep alignment */ | ||
76 | |||
77 | .end_b1: | ||
78 | mov r4,r1 /* r1 = start_address... */ | ||
79 | add #11,r1 /* ... + 11, combined for rounding and offset */ | ||
80 | xor r1,r0 | ||
81 | tst #4,r0 /* bit 2 tells whether an even or odd number of */ | ||
82 | bf .loop_odd /* longwords to set */ | ||
83 | |||
84 | /* main loop: set 2 longs per pass */ | ||
85 | .loop_2l: | ||
86 | mov.l r5,@-r6 /* store first long */ | ||
87 | .loop_odd: | ||
88 | cmp/hi r1,r6 /* runs r6 down to first long bound */ | ||
89 | mov.l r5,@-r6 /* store second long */ | ||
90 | bt .loop_2l | ||
91 | |||
92 | .no_longs: | ||
93 | cmp/hi r4,r6 /* any bytes left? */ | ||
94 | bf .end_b2 /* no: skip loop */ | ||
95 | |||
96 | /* trailing byte loop */ | ||
97 | .loop_b2: | ||
98 | mov.b r5,@-r6 /* store byte */ | ||
99 | cmp/hi r4,r6 /* runs r6 down to the start address */ | ||
100 | bt .loop_b2 | ||
101 | |||
102 | .end_b2: | ||
103 | rts | ||
104 | mov r4,r0 /* return start address */ | ||
105 | |||
106 | .end: | ||
107 | .size _memset,.end-_memset | ||
diff --git a/firmware/target/sh/strlen-sh.S b/firmware/target/sh/strlen-sh.S new file mode 100755 index 0000000000..34837605ac --- /dev/null +++ b/firmware/target/sh/strlen-sh.S | |||
@@ -0,0 +1,94 @@ | |||
1 | /*************************************************************************** | ||
2 | * __________ __ ___. | ||
3 | * Open \______ \ ____ ____ | | _\_ |__ _______ ___ | ||
4 | * Source | _// _ \_/ ___\| |/ /| __ \ / _ \ \/ / | ||
5 | * Jukebox | | ( <_> ) \___| < | \_\ ( <_> > < < | ||
6 | * Firmware |____|_ /\____/ \___ >__|_ \|___ /\____/__/\_ \ | ||
7 | * \/ \/ \/ \/ \/ | ||
8 | * $Id$ | ||
9 | * | ||
10 | * Copyright (C) 2005 by Jens Arnold | ||
11 | * | ||
12 | * All files in this archive are subject to the GNU General Public License. | ||
13 | * See the file COPYING in the source tree root for full license agreement. | ||
14 | * | ||
15 | * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY | ||
16 | * KIND, either express or implied. | ||
17 | * | ||
18 | ****************************************************************************/ | ||
19 | #include "config.h" | ||
20 | |||
21 | .section .icode,"ax",@progbits | ||
22 | |||
23 | .align 2 | ||
24 | .global _strlen | ||
25 | .type _strlen,@function | ||
26 | |||
27 | /* Works out the length of a string | ||
28 | * This version is optimized for speed | ||
29 | * | ||
30 | * arguments: | ||
31 | * r4 - start address | ||
32 | * | ||
33 | * return value: | ||
34 | * r0 - string length | ||
35 | * | ||
36 | * register usage: | ||
37 | * r0 - current address | ||
38 | * r1 - current value (byte/long) | ||
39 | * r2 - mask for alignment / zero (for cmp/str) | ||
40 | * r4 - start address | ||
41 | * | ||
42 | */ | ||
43 | |||
44 | _strlen: | ||
45 | mov r4,r0 /* r0 = start address */ | ||
46 | tst #3,r0 /* long aligned? */ | ||
47 | bt .start_l /* yes, jump directly to the longword loop */ | ||
48 | |||
49 | /* not long aligned: check the first 3 bytes */ | ||
50 | mov.b @r0+,r1 /* fetch first byte */ | ||
51 | tst r1,r1 /* byte == 0 ? */ | ||
52 | bt .hitzero /* yes, string end found */ | ||
53 | mov.b @r0+,r1 /* fetch second byte */ | ||
54 | mov #3,r2 /* prepare mask: r2 = 0..00000011b */ | ||
55 | tst r1,r1 /* byte == 0 ? */ | ||
56 | bt .hitzero /* yes, string end found */ | ||
57 | mov.b @r0+,r1 /* fetch third byte */ | ||
58 | not r2,r2 /* prepare mask: r2 = 1..11111100b */ | ||
59 | tst r1,r1 /* byte == 0 ? */ | ||
60 | bt .hitzero /* yes, string end found */ | ||
61 | |||
62 | /* not yet found, fall through into longword loop */ | ||
63 | and r2,r0 /* align down to long bound */ | ||
64 | |||
65 | /* main loop: check longwords */ | ||
66 | .start_l: | ||
67 | mov #0,r2 /* zero longword for cmp/str */ | ||
68 | .loop_l: | ||
69 | mov.l @r0+,r1 /* fetch long word */ | ||
70 | cmp/str r1,r2 /* any zero byte within? */ | ||
71 | bf .loop_l /* no, loop */ | ||
72 | add #-4,r0 /* set address back to start of this longword */ | ||
73 | |||
74 | /* the last longword contains the string end: figure out the byte */ | ||
75 | mov.b @r0+,r1 /* fetch first byte */ | ||
76 | tst r1,r1 /* byte == 0 ? */ | ||
77 | bt .hitzero /* yes, string end found */ | ||
78 | mov.b @r0+,r1 /* fetch second byte */ | ||
79 | tst r1,r1 /* byte == 0 ? */ | ||
80 | bt .hitzero /* yes, string end found */ | ||
81 | mov.b @r0+,r1 /* fetch third byte */ | ||
82 | tst r1,r1 /* byte == 0 ? */ | ||
83 | bt .hitzero /* yes, string end found */ | ||
84 | rts /* must be the fourth byte */ | ||
85 | sub r4,r0 /* len = string_end - string_start */ | ||
86 | |||
87 | .hitzero: | ||
88 | add #-1,r0 /* undo address increment */ | ||
89 | rts | ||
90 | sub r4,r0 /* len = string_end - string_start */ | ||
91 | |||
92 | .end: | ||
93 | .size _strlen,.end-_strlen | ||
94 | |||