diff options
author | Dominik Riebeling <Dominik.Riebeling@gmail.com> | 2021-12-15 21:04:28 +0100 |
---|---|---|
committer | Dominik Riebeling <Dominik.Riebeling@gmail.com> | 2021-12-24 18:05:53 +0100 |
commit | c876d3bbefe0dc00c27ca0c12d29da5874946962 (patch) | |
tree | 69f468a185a369b01998314bc3ecc19b70f4fcaa /utils/mkamsboot/dualboot/nrv2e_d8.S | |
parent | 6c6f0757d7a902feb293be165d1490c42bc8e7ad (diff) | |
download | rockbox-c876d3bbefe0dc00c27ca0c12d29da5874946962.tar.gz rockbox-c876d3bbefe0dc00c27ca0c12d29da5874946962.zip |
rbutil: Merge rbutil with utils folder.
rbutil uses several components from the utils folder, and can be
considered part of utils too. Having it in a separate folder is an
arbitrary split that doesn't help anymore these days, so merge them.
This also allows other utils to easily use libtools.make without the
need to navigate to a different folder.
Change-Id: I3fc2f4de19e3e776553efb5dea5f779dfec0dc21
Diffstat (limited to 'utils/mkamsboot/dualboot/nrv2e_d8.S')
-rw-r--r-- | utils/mkamsboot/dualboot/nrv2e_d8.S | 198 |
1 files changed, 198 insertions, 0 deletions
diff --git a/utils/mkamsboot/dualboot/nrv2e_d8.S b/utils/mkamsboot/dualboot/nrv2e_d8.S new file mode 100644 index 0000000000..d24fb94b2a --- /dev/null +++ b/utils/mkamsboot/dualboot/nrv2e_d8.S | |||
@@ -0,0 +1,198 @@ | |||
1 | /* arm_nrv2e_d8.S -- ARM decompressor for NRV2E | ||
2 | |||
3 | This file is part of the UPX executable compressor. | ||
4 | |||
5 | Copyright (C) 1996-2008 Markus Franz Xaver Johannes Oberhumer | ||
6 | Copyright (C) 1996-2008 Laszlo Molnar | ||
7 | Copyright (C) 2000-2008 John F. Reiser | ||
8 | All Rights Reserved. | ||
9 | |||
10 | UPX and the UCL library are free software; you can redistribute them | ||
11 | and/or modify them under the terms of the GNU General Public License as | ||
12 | published by the Free Software Foundation; either version 2 of | ||
13 | the License, or (at your option) any later version. | ||
14 | |||
15 | This program is distributed in the hope that it will be useful, | ||
16 | but WITHOUT ANY WARRANTY; without even the implied warranty of | ||
17 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | ||
18 | GNU General Public License for more details. | ||
19 | |||
20 | You should have received a copy of the GNU General Public License | ||
21 | along with this program; see the file COPYING. | ||
22 | If not, write to the Free Software Foundation, Inc., | ||
23 | 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. | ||
24 | |||
25 | Markus F.X.J. Oberhumer Laszlo Molnar | ||
26 | <markus@oberhumer.com> <ml1050@users.sourceforge.net> | ||
27 | |||
28 | John F. Reiser | ||
29 | <jreiser@users.sourceforge.net> | ||
30 | */ | ||
31 | #define SAFE 0 /* 1 for src+dst bounds checking: cost 40 bytes */ | ||
32 | |||
33 | #define src r0 | ||
34 | #define len r1 /* overlaps 'cnt' */ | ||
35 | #define dst r2 | ||
36 | #define tmp r3 | ||
37 | #define bits r4 | ||
38 | #define off r5 | ||
39 | #define wrnk r6 /* 0x500 M2_MAX_OFFSET before "wrinkle" */ | ||
40 | #define srclim r7 | ||
41 | #if 1==SAFE /*{*/ | ||
42 | #define dstlim r12 | ||
43 | #endif /*}*/ | ||
44 | |||
45 | #define cnt r1 /* overlaps 'len' while reading an offset */ | ||
46 | |||
47 | #if 1==SAFE /*{*/ | ||
48 | #define CHECK_SRC cmp src,srclim; bhs bad_src_n2e | ||
49 | #define CHECK_DST cmp dst,dstlim; bhs bad_dst_n2e | ||
50 | #else /*}{*/ | ||
51 | #define CHECK_SRC /*empty*/ | ||
52 | #define CHECK_DST /*empty*/ | ||
53 | #endif /*}*/ | ||
54 | |||
55 | #if 0 /*{ DEBUG only: check newly-decompressed against original dst */ | ||
56 | #define CHECK_BYTE \ | ||
57 | push {wrnk}; \ | ||
58 | ldrb wrnk,[dst]; \ | ||
59 | cmp wrnk,tmp; beq 0f; bkpt; \ | ||
60 | 0: pop {wrnk} | ||
61 | #else /*}{*/ | ||
62 | #define CHECK_BYTE /*empty*/ | ||
63 | #endif /*}*/ | ||
64 | |||
65 | /* "mov lr,pc; bxx ..." implements conditional subroutine call | ||
66 | * | ||
67 | * NOTE: the lsb will not be set, so you MUST NOT use 'bx lr' to return, | ||
68 | * else the T bit will be cleared and processor will go in ARM state */ | ||
69 | #define GETBIT add bits,bits; mov lr,pc; beq get1_n2e | ||
70 | |||
71 | #define getnextb(reg) GETBIT; adc reg,reg | ||
72 | #define jnextb0 GETBIT; bcc | ||
73 | #define jnextb1 GETBIT; bcs | ||
74 | |||
75 | #ifndef PURE_THUMB | ||
76 | ucl_nrv2e_decompress_8: .globl ucl_nrv2e_decompress_8 @ ARM mode | ||
77 | .type ucl_nrv2e_decompress_8, %function | ||
78 | /* error = (*)(char const *src, int len_src, char *dst, int *plen_dst) | ||
79 | Actual decompressed length is stored through plen_dst. | ||
80 | For SAFE mode: at call, *plen_dst must be allowed length of output buffer. | ||
81 | */ | ||
82 | adr r12,1+.thumb_nrv2e_d8; bx r12 @ enter THUMB mode | ||
83 | #endif | ||
84 | .code 16 @ THUMB mode | ||
85 | .thumb_func | ||
86 | |||
87 | .thumb_nrv2e_d8: | ||
88 | #if 0 | ||
89 | push {r2,r3, r4,r5,r6,r7, lr} | ||
90 | #define sp_DST0 0 /* stack offset of original dst */ | ||
91 | #endif | ||
92 | add srclim,len,src @ srclim= eof_src; | ||
93 | #if 1==SAFE /*{*/ | ||
94 | ldr tmp,[r3] @ len_dst | ||
95 | add tmp,dst | ||
96 | mov dstlim,tmp | ||
97 | #endif /*}*/ | ||
98 | mov bits,#1; neg off,bits @ off= -1 initial condition | ||
99 | lsl bits,#31 @ 1<<31: refill next time | ||
100 | mov wrnk,#5 | ||
101 | lsl wrnk,#8 @ 0x500 @ nrv2e M2_MAX_OFFSET | ||
102 | b top_n2e | ||
103 | |||
104 | #if 1==SAFE /*{*/ | ||
105 | bad_dst_n2e: # return value will be 2 | ||
106 | add src,srclim,#1 | ||
107 | bad_src_n2e: # return value will be 1 | ||
108 | add src,#1 | ||
109 | #endif /*}*/ | ||
110 | eof_n2e: | ||
111 | #if 0 | ||
112 | pop {r3,r4} @ r3= orig_dst; r4= plen_dst | ||
113 | sub src,srclim @ 0 if actual src length equals expected length | ||
114 | sub dst,r3 @ actual dst length | ||
115 | str dst,[r4] | ||
116 | pop {r4,r5,r6,r7 /*,pc*/} | ||
117 | pop {r1}; bx r1 @ "pop {,pc}" fails return to ARM mode on ARMv4T | ||
118 | #else | ||
119 | mov r0, #0 | ||
120 | bx r0 /* Branch to 0x0, switch to ARM mode */ | ||
121 | #endif | ||
122 | |||
123 | get1_n2e: @ In: Carry set [from adding 0x80000000 (1<<31) to itself] | ||
124 | ldrb bits,[src] @ zero-extend next byte | ||
125 | adc bits,bits @ double and insert CarryIn as low bit | ||
126 | CHECK_SRC | ||
127 | add src,#1 | ||
128 | lsl bits,#24 @ move to top byte, and set CarryOut from old bit 8 | ||
129 | /* NOTE: the following instruction will not work on ARMv7+, because | ||
130 | * it will update the T bit and return into ARM state */ | ||
131 | mov pc,lr @ return, stay in current (THUMB) mode | ||
132 | |||
133 | lit_n2e: | ||
134 | CHECK_SRC; ldrb tmp,[src]; add src,#1 | ||
135 | CHECK_BYTE | ||
136 | CHECK_DST; strb tmp,[dst]; add dst,#1 | ||
137 | top_n2e: | ||
138 | jnextb1 lit_n2e | ||
139 | mov cnt,#1; b getoff_n2e | ||
140 | |||
141 | off_n2e: | ||
142 | sub cnt,#1 | ||
143 | getnextb(cnt) | ||
144 | getoff_n2e: | ||
145 | getnextb(cnt) | ||
146 | jnextb0 off_n2e | ||
147 | |||
148 | sub tmp,cnt,#3 @ set Carry | ||
149 | mov len,#0 @ Carry unaffected | ||
150 | blo offprev_n2e @ cnt was 2; tests Carry only | ||
151 | lsl tmp,#8 | ||
152 | CHECK_SRC; ldrb off,[src]; add src,#1 @ low 7+1 bits | ||
153 | orr off,tmp | ||
154 | mvn off,off; beq eof_n2e @ off= ~off | ||
155 | asr off,#1; bcs lenlast_n2e | ||
156 | b lenmore_n2e | ||
157 | |||
158 | offprev_n2e: | ||
159 | jnextb1 lenlast_n2e | ||
160 | lenmore_n2e: | ||
161 | mov len,#1 | ||
162 | jnextb1 lenlast_n2e | ||
163 | len_n2e: | ||
164 | getnextb(len) | ||
165 | jnextb0 len_n2e | ||
166 | add len,#6-2 | ||
167 | b gotlen_n2e | ||
168 | |||
169 | lenlast_n2e: | ||
170 | getnextb(len) @ 0,1,2,3 | ||
171 | add len,#2 | ||
172 | gotlen_n2e: @ 'cmn': add the inputs, set condition codes, discard the sum | ||
173 | cmn wrnk,off; bcs near_n2e @ within M2_MAX_OFFSET | ||
174 | add len,#1 @ too far away, so minimum match length is 3 | ||
175 | near_n2e: | ||
176 | #if 1==SAFE /*{*/ | ||
177 | ldr tmp,[sp,#sp_DST0] | ||
178 | sub tmp,dst | ||
179 | sub tmp,off; bhi bad_dst_n2e @ reaching back too far | ||
180 | |||
181 | add tmp,dst,cnt | ||
182 | cmp tmp,dstlim; bhi bad_dst_n2e @ too much output | ||
183 | #endif /*}*/ | ||
184 | ldrb tmp,[dst] @ force cacheline allocate | ||
185 | copy_n2e: | ||
186 | ldrb tmp,[dst,off] | ||
187 | CHECK_BYTE | ||
188 | strb tmp,[dst]; add dst,#1 | ||
189 | sub len,#1; bne copy_n2e | ||
190 | b top_n2e | ||
191 | |||
192 | #ifndef PURE_THUMB | ||
193 | .size ucl_nrv2e_decompress_8, .-ucl_nrv2e_decompress_8 | ||
194 | #endif | ||
195 | |||
196 | /* | ||
197 | vi:ts=8:et:nowrap | ||
198 | */ | ||