From 346423c040fe4ac31dae7c1afcb1d853cc80635c Mon Sep 17 00:00:00 2001
From: Cástor Muñoz <cmvidal@gmail.com>
Date: Thu, 4 Feb 2016 23:05:17 +0100
Subject: mks5lboot v1.0 - dualboot installer for s5l8702 targets

A tool to install/uninstall a bootloader into a s5l8702 based device:

- iPod Classic 6G
- iPod Nano 3G (TODO)

See mks5lboot/README for detailed info.

Change-Id: I451d2aaff34509ebd356e4660647e5222c5d3409
---
 rbutil/mks5lboot/dualboot/dualboot.lds | 59 ++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 rbutil/mks5lboot/dualboot/dualboot.lds

(limited to 'rbutil/mks5lboot/dualboot/dualboot.lds')

diff --git a/rbutil/mks5lboot/dualboot/dualboot.lds b/rbutil/mks5lboot/dualboot/dualboot.lds
new file mode 100644
index 0000000000..cb92e2a286
--- /dev/null
+++ b/rbutil/mks5lboot/dualboot/dualboot.lds
@@ -0,0 +1,59 @@
+#define ASM
+#include "config.h"
+#include "cpu.h"
+#include "mks5lboot.h"
+
+ENTRY(_start)
+OUTPUT_FORMAT(elf32-littlearm)
+OUTPUT_ARCH(arm)
+
+#define BIN_ORIG    DFU_LOADADDR + BIN_OFFSET
+#define BIN_SIZE    MAX_PAYLOAD
+
+MEMORY
+{
+    IRAM : ORIGIN = BIN_ORIG, LENGTH = BIN_SIZE
+}
+
+SECTIONS
+{
+    .text : {
+        *(.init.text*)
+        *(.text*)
+        *(.icode*)
+        . = ALIGN(4);
+    } > IRAM
+
+    /* include initialized BSS (if any) into DFU image */
+    .bss : {
+        *(.bss*)
+        *(.ibss*)
+        *(COMMON)
+        . = ALIGN(4);
+    } > IRAM
+
+#if 1
+    /* reuse pwnage as stack, 0x30c bytes available */
+    _exception_stack = BIN_ORIG;
+    _supervisor_stack = _exception_stack;
+#else
+    /* include stack into DFU image */
+    .stack : {
+       . += 0x400;
+       _supervisor_stack = .;
+       . += 0x200;
+       _exception_stack = .;
+    } > IRAM
+#endif
+
+    .data : {
+        *(.data*)
+        *(.rodata*)
+        *(.idata*)
+        *(.irodata*)
+        /* place bootloader IM3 header at the end, mkdfu
+           will concatenate the bootloader binary here */
+        . = ALIGN(16);
+        *(.im3info.data*)
+    } > IRAM
+}
-- 
cgit v1.2.3