From 28d54c6016459ffe93c0be2efea7de27c38d783c Mon Sep 17 00:00:00 2001
From: Marcin Bukat <marcin.bukat@gmail.com>
Date: Mon, 26 Apr 2010 21:40:16 +0000
Subject: Add MPIO HD200 port - new files

git-svn-id: svn://svn.rockbox.org/rockbox/trunk@25725 a1c6a512-1295-4272-9138-f99709370657
---
 firmware/target/coldfire/mpio/boot.lds.flash | 81 ++++++++++++++++++++++++++++
 1 file changed, 81 insertions(+)
 create mode 100644 firmware/target/coldfire/mpio/boot.lds.flash

(limited to 'firmware/target/coldfire/mpio/boot.lds.flash')

diff --git a/firmware/target/coldfire/mpio/boot.lds.flash b/firmware/target/coldfire/mpio/boot.lds.flash
new file mode 100644
index 0000000000..2b086586ad
--- /dev/null
+++ b/firmware/target/coldfire/mpio/boot.lds.flash
@@ -0,0 +1,81 @@
+#include "config.h"
+
+ENTRY(start)
+OUTPUT_FORMAT(elf32-m68k)
+STARTUP(target/coldfire/crt0.o)
+
+#define DRAMSIZE (MEMORYSIZE * 0x100000)
+
+#define DRAMORIG 0x31000000
+#define IRAMORIG 0x10000000
+#define IRAMSIZE 0x18000
+#define FLASHORIG 0x000e0000
+#define FLASHSIZE 0x1f800
+
+MEMORY
+{
+   DRAM : ORIGIN = DRAMORIG, LENGTH = DRAMSIZE
+   IRAM : ORIGIN = IRAMORIG, LENGTH = IRAMSIZE
+   FLASH : ORIGIN = FLASHORIG, LENGTH = FLASHSIZE
+}
+
+SECTIONS
+{
+    .vectors :
+    {
+        _datacopy = .;
+    } > FLASH
+
+    .data : AT ( _datacopy )
+    {
+        _datastart = .;
+        KEEP(*(.resetvectors));
+        *(.resetvectors);
+        KEEP(*(.vectors));
+        *(.vectors);
+        . = ALIGN(0x200);
+        *(.icode)
+        *(.irodata)
+        *(.idata)
+        *(.data*)
+        . = ALIGN(0x4);
+        _dataend = .;
+        . = ALIGN(0x10);  /* Maintain proper alignment for .text section */
+    } > IRAM
+
+    /* TRICK ALERT! Newer versions of the linker don't allow output sections
+       to overlap even if one of them is empty, so advance the location pointer
+       "by hand" */
+    .text LOADADDR(.data) + SIZEOF(.data) :
+    {
+        *(.init.text)
+        *(.text*)
+        . = ALIGN(0x4);
+    } > FLASH
+
+    .rodata :
+    {
+        *(.rodata*)
+        . = ALIGN(0x4);
+        _iramcopy = .;
+    } > FLASH
+
+    .stack :
+    {
+       *(.stack)
+       _stackbegin = .;
+       stackbegin = .;
+       . += 0x2000;
+       _stackend = .;
+       stackend = .;
+    } > IRAM
+
+    .bss DRAMORIG+0x800000:
+    {
+       _edata = .;
+        *(.ibss)
+        *(.bss*)
+        *(COMMON)
+       _end = .;
+    } > DRAM
+}
-- 
cgit v1.2.3