From 553626a9582a266f99134f735759e63da0a44714 Mon Sep 17 00:00:00 2001
From: Frank Gevaerts <frank@gevaerts.be>
Date: Mon, 18 Jan 2010 19:05:20 +0000
Subject: Add initial Packard Bell Vibe 500 port, by Szymon Dziok

Author: Szymon Dziok
Flyspray: FS#10912


git-svn-id: svn://svn.rockbox.org/rockbox/trunk@24276 a1c6a512-1295-4272-9138-f99709370657
---
 firmware/target/arm/pbell/boot.lds | 64 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 firmware/target/arm/pbell/boot.lds

(limited to 'firmware/target/arm/pbell/boot.lds')

diff --git a/firmware/target/arm/pbell/boot.lds b/firmware/target/arm/pbell/boot.lds
new file mode 100644
index 0000000000..ccc68c0916
--- /dev/null
+++ b/firmware/target/arm/pbell/boot.lds
@@ -0,0 +1,64 @@
+#include "config.h"
+
+ENTRY(start)
+OUTPUT_FORMAT(elf32-littlearm)
+OUTPUT_ARCH(arm)
+STARTUP(target/arm/crt0-pp-bl.o)
+
+#define DRAMSIZE (MEMORYSIZE * 0x100000)
+
+#define DRAMORIG 0x10000000
+#define IRAMORIG 0x40000000
+#define IRAMSIZE 0x18000
+#define FLASHORIG 0x001f0000
+#define FLASHSIZE 2M
+
+MEMORY
+{
+    DRAM : ORIGIN = DRAMORIG, LENGTH = DRAMSIZE
+    IRAM : ORIGIN = IRAMORIG, LENGTH = IRAMSIZE
+}
+
+SECTIONS
+{
+  . = IRAMORIG;
+
+  .text : {
+    *(.init.text)
+    *(.text*)
+    *(.glue_7)
+    *(.glue_7t)
+  } > IRAM
+
+  .data : {
+    *(.icode)
+    *(.irodata)
+    *(.idata)
+    *(.data*)
+    *(.ncdata*)
+    *(.rodata*)
+    _dataend = . ;
+  } > IRAM
+
+  .stack : {
+     *(.stack)
+     _stackbegin = .;
+     stackbegin = .;
+     . += 0x2000;
+     _stackend = .;
+     stackend = .;
+  } > IRAM
+
+  /* The bss section is too large for IRAM - we just move it 16MB into the
+     DRAM */
+
+  . = DRAMORIG;
+  .bss . + (16*1024*1024) : {
+     _edata = .;
+     *(.bss*);
+     *(.ibss);
+     *(COMMON)
+     *(.ncbss*);
+     _end = .;
+  } > DRAM
+}
-- 
cgit v1.2.3