hwstub: add jz4760b stub

The stub is quite versatile: it can be loaded using bootrom or another other
means (like factory boot on Fiio X1). It relocates itself to TCSM0 and provides
basic functionality (it does not recover from failed read/writes at the moment).

Change-Id: Ib646a4b43fba9358d6f93f0f73a5c2e9bcd775a7

1 files changed, 55 insertions, 0 deletions

diff --git a/utils/hwstub/stub/jz4760b/hwstub.lds b/utils/hwstub/stub/jz4760b/hwstub.lds
new file mode 100644
index 0000000000..33aad51ebd
--- /dev/null
+++ b/utils/hwstub/stub/jz4760b/hwstub.lds
@@ -0,0 +1,55 @@
+#include "config.h"
+ENTRY(main)
+OUTPUT_ARCH(mips)
+STARTUP(jz4760b/crt0.o)
+
+MEMORY
+{
+    /* see crt0.S from an an explanation of why TCSM0 is the best choice */
+    TCSM0 : ORIGIN = TCSM0_ORIG, LENGTH = TCSM0_SIZE
+}
+
+SECTIONS
+{
+    .itext :
+    {
+        relocstart = .;
+        oc_codestart = .;
+        *(.init.text*)
+        *(.text*)
+        *(.icode*)
+        *(.data*)
+        *(.rodata*)
+        . = ALIGN(4);
+        relocend = .;
+    } > TCSM0
+
+    .bss (NOLOAD) :
+    {
+        bssbegin = .;
+        *(.bss)
+        . = ALIGN(4);
+        bssend = .;
+    } > TCSM0
+
+    .stack (NOLOAD) :
+    {
+        oc_codeend = .;
+        oc_stackstart = .;
+        . += STACK_SIZE;
+        oc_stackend = .;
+        oc_bufferstart = .;
+    } > TCSM0
+
+    .ocend TCSM0_ORIG + TCSM0_SIZE (NOLOAD) :
+    {
+        oc_bufferend = .;
+    } > TCSM0
+
+    /DISCARD/ :
+    {
+        *(.note.*)
+        *(.reginfo*)
+        *(.MIPS*)
+    }
+}